إعداد AWS PrivateLink لإتاحة MSK لـ ClickPipes

خطوات الإعداد لإتاحة MSK خاص عبر اتصال multi-VPC لـ MSK إلى ClickPipes.

​

نظرة عامة

سيرشدك هذا الدليل إلى كيفية البدء بإعداد MSK multi-VPC لاستخدامه مع ClickPipes نقطة نهاية خاصة عكسية.

تمتلك ClickPipes شبكة VPC للعميل وتنشئ اتصال VPC مُدارًا. ولإنشاء اتصال الشبكة، فعّل الاتصال الخاص متعدد VPC على عنقود MSK لديك، وامنح AWS account الخاص بـ ClickPipes تفويضًا في سياسة cluster.

​

المتطلبات

يجب أن تكون شبكة VPC الخاصة بـ عنقود MSK لديك في إحدى مناطق ClickPipes لدينا. راجع مناطق ClickPipes للاطلاع على قائمة المناطق المدعومة.

​

تمكين اتصال multi-VPC

وحدة تحكم AWS

1. انتقل إلى عنقود MSK.
   • اختر “Clusters” من جزء التنقل الأيسر في Console الخاص بـ Amazon MSK.
   • حدّد عنقود MSK الذي تريد تهيئته لاتصال multi-VPC.
2. فعّل اتصال multi-VPC لـ MSK
   • في علامة التبويب Connectivity، ابحث عن قسم اتصال multi-VPC.
   • انقر على Edit.
   • فعّل خيار Turn-on اتصال multi-VPC لـ MSK.
   • اتبع التعليمات
3. أضف principal الخاص بحساب ClickPipes إلى سياسة العنقود
   • انتقل إلى علامة التبويب Configuration.
   • انقر على Edit في قسم Cluster policy.
   • أدرج arn:aws:iam::072088201116:root في سياسة IAM. مثال:
     {
         "Version": "2012-10-17",
         "Statement": [
             {
                 "Effect": "Allow",
                 "Principal": {
                     "AWS": [
                         "arn:aws:iam::072088201116:root"
                     ]
                 },
                 "Action": [
                     "kafka:CreateVpcConnection",
                     "kafka:GetBootstrapBrokers",
                     "kafka:DescribeCluster",
                     "kafka:DescribeClusterV2"
                 ],
                 "Resource": "<MSK_CLUSTER_ARN>"
             }
         ]
     }
     

Terraform

فعّل طريقة مصادقة MSK لكلٍّ من العنقود واتصال multi-VPC. يستخدم المثال التالي SASL/IAM؛ وبدلًا من ذلك، عيّن scram = true لاستخدام SASL/SCRAM.

resource "aws_msk_cluster" "this" {
  # ... الإعدادات الحالية ...

  client_authentication {
    sasl {
      iam = true
    }
  }

  broker_node_group_info {
    # ... الإعدادات الحالية ...

    connectivity_info {
      vpc_connectivity {
        client_authentication {
          sasl {
            iam = true
          }
        }
      }
    }
  }
}

خوّل حساب AWS الخاص بـ ClickPipes في سياسة عنقود MSK:

resource "aws_msk_cluster_policy" "clickpipes" {
  cluster_arn = aws_msk_cluster.this.arn

  policy = jsonencode({
    Version = "2012-10-17"
    Statement = [{
      Sid       = "ClickPipesMultiVpc"
      Effect    = "Allow"
      Principal = { AWS = "arn:aws:iam::072088201116:root" }
      Action = [
        "kafka:CreateVpcConnection",
        "kafka:GetBootstrapBrokers",
        "kafka:DescribeCluster",
        "kafka:DescribeClusterV2",
      ]
      Resource = aws_msk_cluster.this.arn
    }]
  })
}

إذا كان للعنقود سياسة موجودة بالفعل، فاحتفظ بعباراتها الحالية عند إضافة أذونات ClickPipes.

تُمكّن سياسة IAM الخاصة بالعنقود ClickPipes من بدء الاتصال من ClickPipes إلى عنقود MSK الخاص بك. إذا كنت تريد تهيئة المصادقة عبر IAM لعنقود MSK الخاص بك، فيُرجى الرجوع إلى وثائق المصادقة عبر IAM.

​

إنشاء نقطة نهاية خاصة عكسية

ClickPipes UI

اتبع خطوات إنشاء نقطة النهاية الخاصة العكسية الواردة في وثائق ClickPipes.

Terraform

أنشئ نقطة النهاية الخاصة العكسية باستخدام موفر ClickHouse لـ Terraform:

resource "clickhouse_clickpipes_reverse_private_endpoint" "msk" {
  service_id         = var.clickhouse_service_id
  description        = "MSK multi-VPC reverse private endpoint"
  type               = "MSK_MULTI_VPC"
  msk_cluster_arn    = aws_msk_cluster.this.arn
  msk_authentication = "SASL_IAM" # أو "SASL_SCRAM"

  depends_on = [aws_msk_cluster_policy.clickpipes]
}

حقول المورد غير قابلة للتغيير. يؤدي تغيير أي حقل إلى حذف نقطة النهاية الخاصة العكسية وإعادة إنشائها.